; I2C test for controlling the I2C servoswitch
; based on Testboard hardware
; converts 3 bytes from serial connection and sends it to TWI
;
; author: Achim Walther, www.voidpointer.de
; version 1.01, 11.05.2005

.include "m8def.inc"

;****************************************************************************
;  TWI State codes
;****************************************************************************/
; General TWI Master staus codes                      
.equ TWI_START		= 0x08  ; START has been transmitted  
.equ TWI_REP_START	= 0x10  ; Repeated START has been transmitted
.equ TWI_ARB_LOST	= 0x38  ; Arbitration lost

; TWI Master Transmitter staus codes                      
.equ TWI_MTX_ADR_ACK	= 0x18  ; SLA+W has been tramsmitted and ACK received
.equ TWI_MTX_ADR_NACK	= 0x20  ; SLA+W has been tramsmitted and NACK received 
.equ TWI_MTX_DATA_ACK	= 0x28  ; Data byte has been tramsmitted and ACK received
.equ TWI_MTX_DATA_NACK	= 0x30  ; Data byte has been tramsmitted and NACK received 

; TWI Master Receiver staus codes  
.equ TWI_MRX_ADR_ACK	= 0x40  ; SLA+R has been tramsmitted and ACK received
.equ TWI_MRX_ADR_NACK	= 0x48  ; SLA+R has been tramsmitted and NACK received
.equ TWI_MRX_DATA_ACK	= 0x50  ; Data byte has been received and ACK tramsmitted
.equ TWI_MRX_DATA_NACK	= 0x58  ; Data byte has been received and NACK tramsmitted

; TWI Slave Transmitter staus codes
.equ TWI_STX_ADR_ACK	= 0xA8  ; Own SLA+R has been received; ACK has been returned
.equ TWI_STX_ADR_ACK_M_ARB_LOST = 0xB0  ; Arbitration lost in SLA+R/W as Master; own SLA+R has been received; ACK has been returned
.equ TWI_STX_DATA_ACK	= 0xB8  ; Data byte in TWDR has been transmitted; ACK has been received
.equ TWI_STX_DATA_NACK	= 0xC0  ; Data byte in TWDR has been transmitted; NOT ACK has been received
.equ TWI_STX_DATA_ACK_LAST_BYTE = 0xC8  ; Last data byte in TWDR has been transmitted (TWEA = '0'); ACK has been received

; TWI Slave Receiver staus codes
.equ TWI_SRX_ADR_ACK	= 0x60  ; Own SLA+W has been received ACK has been returned
.equ TWI_SRX_ADR_ACK_M_ARB_LOST = 0x68  ; Arbitration lost in SLA+R/W as Master; own SLA+W has been received; ACK has been returned
.equ TWI_SRX_GEN_ACK	= 0x70  ; General call address has been received; ACK has been returned
.equ TWI_SRX_GEN_ACK_M_ARB_LOST = 0x78  ; Arbitration lost in SLA+R/W as Master; General call address has been received; ACK has been returned
.equ TWI_SRX_ADR_DATA_ACK       = 0x80  ; Previously addressed with own SLA+W; data has been received; ACK has been returned
.equ TWI_SRX_ADR_DATA_NACK      = 0x88  ; Previously addressed with own SLA+W; data has been received; NOT ACK has been returned
.equ TWI_SRX_GEN_DATA_ACK       = 0x90  ; Previously addressed with general call; data has been received; ACK has been returned
.equ TWI_SRX_GEN_DATA_NACK      = 0x98  ; Previously addressed with general call; data has been received; NOT ACK has been returned
.equ TWI_SRX_STOP_RESTART       = 0xA0  ; A STOP condition or repeated START condition has been received while still addressed as Slave

; TWI Miscellaneous status codes
.equ TWI_NO_STATE	= 0xF8  ; No relevant state information available; TWINT = '0'
.equ TWI_BUS_ERROR	= 0x00  ; Bus error due to an illegal START or STOP condition
;*****************************************************************************************

.def char0 = R12
.def charA = R13
.def save = R14
.def regs = R15
.def temp = R16
.def data = R17
.def flag = R19

.equ ram = 0x100		; temporary space for keeping UART commands

;.equ CLOCK = 8000000
.equ CLOCK = 4000000
.equ BAUD = 9600
.equ UBRRVAL = CLOCK/(BAUD*16)-1

.equ SERVOSW_W = 0b11000000

intvect:
	rjmp init		; RESET	
	reti			; INT0
	reti			; INT1
	reti			; T2 Compare
	reti			; T2 Overflow
	reti			; T1 Capture
	reti			; T1 Compare A
	reti			; T1 Compare B
	reti			; T1 Overflow
	reti			; T0 Overflow
	reti			; SPI Transfer complete
	rjmp int_rxc		; UART RX Complete
	reti			; UDR Empty
	reti			; UART TX Complete
	reti			; ADC complete
	reti			; EEPROM Ready
	reti			; Analog Comparator
	reti			; TWM
	reti			; SPM_RDY

init:
	; init stack pointer
	ldi temp, LOW(RAMEND)
	out SPL, temp
	ldi temp, HIGH(RAMEND)
	out SPH, temp

	; LED debugging
	ldi temp, 0b00000001
	out DDRC, temp		; configure PinC 0-3 for output

	ldi temp, 0b00000001
	out PORTC, temp		; switch all LEDs off

	ldi flag, 0

	; init registers for hexout
	ldi temp, '0'
	mov char0, temp
	ldi temp, 'A'-10
	mov charA, temp

	; init TWI
	;ldi temp, 32			; TWI clock 100kHz at 8 MHz
	ldi temp, 12			; TWI clock 100kHz at 4 MHz
	out TWBR, temp
	ldi temp, 0xFF
	out TWDR, temp			; Default content = SDA released
	ldi temp, (1<<TWEN)| (0<<TWIE)|(0<<TWINT)|(0<<TWEA)|(0<<TWSTA)|(0<<TWSTO)|(0<<TWWC)
	           			; Enable TWI-interface and release TWI pins.
                    			; Disable Interupt.
                			; No Signal requests.
	out TWCR, temp

	; init UART
	ldi temp, LOW(UBRRVAL)	; set baud rate
	out UBRRL, temp
	ldi temp, HIGH(UBRRVAL)
	out UBRRH, temp


	ldi temp, (1<<URSEL)|(3<<UCSZ0)		; Frame-Format: 8 Bit
	out UCSRC, temp

	sbi UCSRB, RXCIE	; Interrupt on receive
	sbi UCSRB, RXEN		; activate RX (receive)

	sbi UCSRB,TXEN		; TX aktivieren

	sei

main:
	; main loop

	ldi temp, 'o'
	rcall serout
	ldi temp, 'k'
	rcall serout
	rcall newline

	; check if a complete message was received via UART and compute it

loop:	cpi flag, '*'		; check flag if a new message was received
	brne loop

	cli			; disable interrupts
	clr flag		; clear the flag register
	clr R23
	clr R22
	clr R21

	; a complete message was stored in memory
	; X is pointing to the end of the message

	; expected message format is "xxxxxx*"
	; where xxxxxx defines the 3 byte command to send via TWI

	; start reading from the last character
	dec XL			; the '*' character is not needed

	ld temp, -X		; get next char
	cpi temp, 'A'
	brlo id3l		; branch if char is a decimal digit
	subi temp, 7		; substract the value of 'A' - '0' - 0x0A
id3l:	subi temp, '0'
	mov R23, temp
	
	ld temp, -X		; get next char
	cpi temp, 'A'
	brlo id3h
	subi temp, 7
id3h:	subi temp, '0'
	swap temp		; swap nibbles to prepare for addition
	add R23, temp

	ld temp, -X		; get next char
	cpi temp, 'A'
	brlo id2l
	subi temp, 7
id2l:	subi temp, '0'
	mov R22, temp
	
	ld temp, -X		; get next char
	cpi temp, 'A'
	brlo id2h
	subi temp, 7
id2h:	subi temp, '0'
	swap temp
	add R22, temp

	ld temp, -X		; get next char
	cpi temp, 'A'
	brlo id1l
	subi temp, 7
id1l:	subi temp, '0'
	mov R21, temp
	
	ld temp, -X		; get next char
	cpi temp, 'A'
	brlo id1h
	subi temp, 7
id1h:	subi temp, '0'
	swap temp
	add R21, temp


	ldi XL, LOW(ram)	; reset X
	ldi XH, HIGH(ram)

	sei			; enable interrupts again

	; now send the values R21, R22, R23 to the servo switch via I2C
	
	ldi temp, 'i'
	rcall serout
	ldi temp, 'c'
	rcall serout
	ldi temp, ':'
	rcall serout
	mov temp, R21
	rcall hexout
	ldi temp, ' '
	rcall serout
	mov temp, R22
	rcall hexout
	ldi temp, ' '
	rcall serout
	mov temp, R23
	rcall hexout
	rcall newline

	; Start
	rcall I2C_Start
	
	; send I2C slave address + W
	ldi data, SERVOSW_W
	rcall I2C_Send_Addr
	
	; send Data
	mov data, R21
	rcall I2C_Send_Data_W

	mov data, R22
	rcall I2C_Send_Data_W

	; send Data
	mov data, R23
	rcall I2C_Send_Data_W

	; Stop
	rcall I2C_Stop

	rjmp main

; Interrupt handler for UART receive
int_rxc:
	in regs, SREG
	push temp

	in temp, UDR
	st X+, temp		; store character to memory
	cpi temp, '*'		; compare with '*'
	brne int_e
	mov flag, temp		; set complete receive flag

int_e:	pop temp
	out SREG, regs
	reti

; convert the content of temp to a readable hex string and output to the serial port
hexout:
	; serial output of the high nibble
	mov save, temp
	lsr temp
	lsr temp
	lsr temp
	lsr temp
	cpi temp, 10
	brge adda1

	add temp, char0		; add ASCII value of '0'
	rjmp adden1
adda1:	add temp, charA		; add ASCII value of 'A'

adden1:	rcall serout

	; serial output of the low nibble
	mov temp, save
	andi temp, 0b00001111
	cpi temp, 10
	brge adda2
	add temp, char0		; add ASCII value of '0'
	rjmp adden2
adda2:	add temp, charA		; add ASCII value of 'A'

adden2:	rcall serout
	mov temp, save		; restore temp
	ret


newline:	; send 0D 0A to serial for a newline
	mov save, temp
	ldi temp, 0x0D
	rcall serout
	ldi temp, 0x0A
	rcall serout
	mov temp, save		; restore temp
	ret

serout:
	sbis UCSRA,UDRE		; wait for UDR ready
	rjmp serout
	out UDR, temp		; serial output
	ret

;******************************************************
; I2C routines
;******************************************************

I2C_Error:
	mov save, temp
	ldi temp, 'E'
	rcall serout
	ldi temp, 'r'
	rcall serout
	ldi temp, 'r'
	rcall serout
	mov temp, save
	rcall hexout
	rcall newline
	rcall I2C_Stop
end:	rjmp main

I2C_wait:
	; Wait for TWINT Flag set. This indicates that the transmission is completed
	in temp, TWCR
	sbrs temp, TWINT
	rjmp I2C_wait
	ret

; used to send a START or a REPEATED START condition
I2C_Start:
	ldi temp, (1<<TWINT)|(1<<TWSTA)|(1<<TWEN)
	out TWCR, temp
	rcall I2C_wait

	; Check value of TWI Status Register. Mask prescaler bits.
	in temp, TWSR
	andi temp, 0xF8

	;rcall hexout	; debug
	;rcall newline

	;If status different from START or REPEATED START go to ERROR
	;cpi temp, TWI_REP_START
	;breq estart
	cpi temp, TWI_START
	brne I2C_Error
estart:	ret

I2C_Send_Addr:
	; Load data into TWDR Register. Clear TWINT bit in TWCR to start transmission of address
	out TWDR, data
	ldi temp, (1<<TWINT) | (1<<TWEN)
	out TWCR, temp

	;Wait for TWINT Flag set. This indicates that the SLA+W has been transmitted, 
	; and ACK/NACK has been received.
	rcall I2C_wait

	; Check value of TWI Status Register. Mask prescaler bits.
	in temp, TWSR
	andi temp, 0xF8

	;rcall hexout	; debug
	;rcall newline

	; compare status with allowed values
	cpi temp, TWI_MTX_ADR_ACK
	breq esenda
	cpi temp, TWI_MTX_ADR_NACK
	brne I2C_Error
esenda:	ret

I2C_Send_Data_W:
	; Load data into TWDR Register. Clear TWINT bit in TWCR to start transmission of address
	out TWDR, data
	ldi temp, (1<<TWINT) | (1<<TWEN)
	out TWCR, temp

	;Wait for TWINT Flag set. This indicates that the SLA+W has been transmitted, 
	; and ACK/NACK has been received.
	rcall I2C_wait

	; Check value of TWI Status Register. Mask prescaler bits.
	in temp, TWSR
	andi temp, 0xF8

	;rcall hexout	; debug
	;rcall newline

	; compare status with allowed values
	cpi temp, TWI_MTX_DATA_ACK
	breq esenda
	cpi temp, TWI_MTX_DATA_NACK
	brne I2C_Error
	ret

I2C_Stop:
	; Transmit STOP condition
	ldi temp, (1<<TWINT)|(1<<TWEN)|(1<<TWSTO)
	out TWCR, temp
	ret